;ipap-hsqmbc
;avance-version (01/03/10)
;
;IPAP-HSQMBC: Measurement of Long-Range Heteronuclear Coupling ;Constants from Spin-State Selective Multiplets 
;
;Journal of Magnetic Resonance, Volume 207
;Issue 2, December 2010,Pages 312-321
;Sergi Gil, Juan Félix Espinosa, Teodor Parella
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"p2=p1*2"
"p4=p3*2"
"d2=1s/(cnst2*2)"
"d4=1s/(cnst2*4)"
"d14=1s/(cnst13*4)"
"d18=1s/(cnst13*8)"
"d11=30m"

"d0=3u"
"in0=inf1/2"
"DELTA1=p16+d16+8u"
"DELTA2=d18-larger(p2,p14)/2"
"DELTA3=d14-d13-p16-d16-p14/2"
"DELTA4=d18-d13-p16-d16-p1-d2-p4/2-p14/2"
"DELTA=p16+d16+50u+p2+d0*2"

1 ze
  4u BLKGRAD
  d11 pl12:f2 
2 d1  
  4u pl1:f1 pl0:f2
3 (p1 ph1)
  DELTA2 
  4u UNBLKGRAD
  (center (p2 ph1) (p14:sp3 ph6):f2 )
  DELTA4
  d13
  p16:gp6
  d16 pl2:f2
  (p1 ph1)
  d2
  (center (p2 ph1):f1 (p4 ph6):f2)
  d2
  (p1 ph8):f1
  d13 pl0:f2
  p16:gp6
  d16
  DELTA4
  (center (p2 ph1) (p14:sp3 ph6):f2 )
  DELTA2 pl2:f2
  (p1 ph2)
  d13
  p16:gp3
  d16
  (p3 ph3):f2
  d0 
  (p2 ph7)
  d0
  50u 
  p16:gp1*EA
  d16
  (p4 ph4):f2
  DELTA

  (p3 ph4):f2
  d13
  p16:gp4
  d16
  	
		if "cnst25==0"
		{
		(p1 ph2)
		}
		else
		{
		(p1 ph1)
		}

  d13
  p16:gp5
  d16 pl0:f2
  DELTA3

		if "cnst25==0"
		{
		(center (p2 ph1) (p14:sp3 ph1):f2 )
		}
		else
		{
		(p2 ph1) 
		}
  
  DELTA3
  d13 pl2:f2
  p16:gp5
  d16
  (p1 ph2)
  DELTA1
  (p2 ph1)
  4u
  p16:gp2
  d16 pl12:f2
  4u BLKGRAD
  go=2 ph31 
  d1  mc #0 to 2 
     F1EA(igrad EA & ip5*2, id0 & ip3*2 & ip6*2 & ip31*2)
exit
   
ph1=0 
ph2=1
ph3=0 2
ph4=0 0 2 2
ph5=1 1 3 3
ph6=0
ph7=0 0 2 2
ph8=2
ph31=0 2 2 0
  
;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p14: f2 channel - 180 degree shaped pulse for inversion
;p16: homospoil/gradient pulse
;d0 : incremented delay (2D)                  [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d2 : 1/(2J)XH
;d4 : 1/(4J)XH
;d14 : 1/(4J) long range XH
;d18 : 1/(8J) long range XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;cnst13: = J(XH) long range
;cnst25: = 0 IP, 1 AP
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 2 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho

;use gradient ratio:	gp 1 : gp 2
;			  80 : 20.1 : 33 : 50 : 17 : 11  for C-13
;			  80 :  8.1 : 33 : 50 : 17 : 11  for N-15

;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13, 8.1% for N-15
;gpz3: 33 %
;gpz4: 50%
;gpz5: 17%
;gpz6: 11%

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100
;gpnam4: SINE.100
;gpnam5: SINE.100
;gpnam6: SINE.100