;1dghsqc
;Double_selective_1DHSQC
;Selincor variant with selective proton and carbon pulses
;avance-version
;1D-HSQC
;1D H-1/X correlation via double inept transfer
;using gradient pulses for selection
;Juan F. Espinosa, Paloma Vidal, Teodor Parella and Sergi Gil:
;Magnetic Resonance in Chemistry, 49, 507-507 (2011).
;DOI:10.1002/mrc.2782

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"p2=p1*2"
"p4=p3*2"
"d4=1s/(cnst2*4)"
"d20=d4-p16-d16"

1  ze 
2  d1 do:f2
3  (p1 ph1)
   d4 pl2:f2
   (center (p13:sp3 ph1) (p4 ph2):f2 )
   d4 UNBLKGRAD
   (p1 ph4) (p3 ph3):f2
   50u
   p16:gp1
   d16 pl0:f2
   (p12:sp2 ph2):f2
   50u
   p16:gp2
   d16 pl2:f2
   (ralign (p1 ph1) (p3 ph5):f2 )
   d4
   (center (p13:sp3 ph1) (p4 ph2):f2 )
   d20
   p16:gp3
   d16
   (p3 ph6):f2
   4u BLKGRAD
   4u pl12:f2
   go=2 ph31 cpd2:f2
   wr #0
   d1 do:f2
exit 


ph1=0
ph2=0 
ph3=0 2
ph4=1
ph5=0
ph6=0
ph31=0 2


;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f1 channel - power level for spin-lock pulse
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p11 : f1 channel - spin-lock pulse
;p12 : f2 channel - 180 shaped pulse
;p13 : f1 channel - 180 shaped pulse
;p16: homospoil/gradient pulse
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;NS: 1 * n
;DS: 16

;use gradient ratio:	gp 1 : gp 2 : gp 3
;			  40 :   -40 : 20.1    for C-13
;			  40 :   -40 :  8.1    for N-15

;for z-only gradients:
;gpz1: 40%
;gpz2: -40%
;gpz3: 20.1% for C-13, 8.1% for N-15

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100