;josep_selhsqmbcco_ipap
;2D proton-selective HSQMBC-TOCSY experiment 
;2D H-1/X correlation via double inept transfer
;phase sensitive using Echo/Antiecho-TPPI gradient selection
;with decoupling during acquisition
;using trim pulses in inept transfer
;using shaped pulses for inversion and refocussing on f2 - channel



#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"d4=1s/(cnst2*4)"
"d11=30m"
"d20=p3"
"d0=3u"
;"in0=inf1/2"
"DELTA1=50u+p16+d16"
"DELTA2=d4-larger(p12,p14)/2-50u-p16-d16"
"DELTA=p16+d16+50u+p2+d0*2+50u"


1 ze
  d11 pl12:f2
2 d1 pl1:f1
3 (p1 ph1)
  50u UNBLKGRAD
  p16:gp6
  d16
  DELTA2 pl0:f2 pl0:f1
  4u
  (center (p12:sp2 ph1) (p14:sp3 ph6):f2 )
  4u
  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp6
  d16
  p28 ph1
  (p1 ph2) 
  50u
  p16:gp3
  d16
  (p3 ph3):f2
  d0 
  (p2 ph5)
  d0
  50u
  p16:gp1*EA
  d16 pl0:f2
  d12
  (p24:sp7 ph14):f2
   DELTA pl2:f2
  (p3 ph4):f2
  50u
  p16:gp4
  d16

  if "cnst25==0"
	{
	(p1 ph2):f1
	}
	else
	{
	(p1 ph1):f1
  }

  50u
  p16:gp5
  d16
  DELTA2 pl0:f2 pl0:f1
  
  if "cnst25==0"
	{
	(center (p2 ph1) (p14:sp3 ph1):f2 )
	}
	else
	{
	(p2 ph1)
  }

  4u
  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp5
  d16
  (p1 ph2):f1
  DELTA1
  (p2 ph1):f1
  50u 
  p16:gp2
  d16 BLKGRAD
  

  if "cnst25==0"
	{
	(p3 ph1):f2
	}
	else
	{
	d20
  	}

  go=2 ph31 
  d1 mc #0 to 2 
     F1EA(igrad EA, id0 & ip3*2 & ip6*2 & ip31*2)
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 2 2
ph5=0
ph6=0
ph14=0 0 2 2
ph31=0 2 2 0


;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;sp3: f2 channel - shaped pulse 180 degree for inversion
;spnam3: Crp60,0.5,20.1 
;sp7: f2 channel - shaped pulse 180 degree for refocussing
;spnam7: Crp60comp.4
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p12: f1 channel - 180 degree shaped pulse [20-80ms]
;p14: f2 channel - 180 degree shaped pulse for inversion
;p16: homospoil/gradient pulse
;p28: f1 channel - trim pulse
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;cnst17: = -0.5 for Crp60comp.4     
;cnst25: = 0 (IP) 
;    = 1 (AP) 
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho


;use gradient ratio:	gp 1 : gp 2
;			  80 : 20.1    for C-13
;			  80 :  8.1    for N-15

;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13, 8.1% for N-15

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100