;sergi_selhsqmbcipap2d
;avance-version (31/05/2011)
;
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"d4=1s/(cnst2*4)"
"d11=30m"
"d0=3u"
"d20=p3"


"in0=inf1/2"


"DELTA1=50u+p16+d16"
"DELTA2=d4-larger(p12,p14)/2-50u-p16-d16-4u"
"DELTA=p16+d16+50u+p2+d0*2+50u"


1 ze
  d11 pl12:f2
2 d1 pl1:f1
3 (p1 ph1)
  50u UNBLKGRAD
  p16:gp6
  d16
  DELTA2 pl0:f2 pl0:f1
  4u
  (center (p12:sp2 ph1) (p14:sp3 ph6):f2 )
  4u
  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp6
  d16
  (p1 ph2) 
  50u
  p16:gp3
  d16
  (p3 ph3):f2
  d0 
  (p2 ph5)
  d0
  50u
  p16:gp1*EA
  d16 pl0:f2
  d12
  (p24:sp7 ph4):f2
   DELTA pl2:f2
  (p3 ph4):f2
  50u
  p16:gp4
  d16

  	if "cnst25==0"
	{
	(p1 ph2):f1
	}
	else
	{
	(p1 ph1):f1
  	}

  50u
  p16:gp5
  d16
  DELTA2 pl0:f2 pl0:f1
  
  	if "cnst25==0"
	{
	(center (p12:sp2 ph1) (p14:sp3 ph1):f2 )
	}
	else
	{
	(p12:sp2 ph1)
  	}

  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp5
  d16
  (p1 ph2):f1
  DELTA1
  (p2 ph1):f1
  50u 
  p16:gp2
  d16 BLKGRAD
 
  if "cnst25==0"
	{
	(p3 ph1):f2
	}
	else
	{
	d20
  	}

  go=2 ph31 
  d1 mc #0 to 2 
     F1EA(igrad EA, id0 & ip3*2 & ip6*2 & ip31*2)
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 0 0 2 2 2 2
ph5=0 0 2 2
ph6=0
ph31=0 2 0 2 2 0 2 0


;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;sp3: f2 channel - shaped pulse 180 degree for inversion
;sp7: f2 channel - shaped pulse 180 degree for refocussing
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p14: f2 channel - 180 degree shaped pulse for inversion
;p16: homospoil/gradient pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse for refocussing
;p28: f1 channel - trim pulse
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence


;use gradient ratio:	gp 1 : gp 2 : gp 3 : gp 4 : gp 5 : gp 6
;			  80 : 20.1 :  33  :  50  :  17  : 11  for C-13
;			  80 :  8.1 :  33  :  50  :  17  : 11    for N-15

;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13, 8.1% for N-15
;gpz3: 33%
;gpz4: 55%
;gpz5: 17%
;gpz6: 11%

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100
;gpnam4: SINE.100
;gpnam5: SINE.100
;gpnam6: SINE.100