;jselhsqmbc
;written by Teo parella & Josep Saurí - 151112
;2D J-selHSQMBC-IPAP experiment
;Simultaneous Measurement of two different J(CHA) and J(CHB) as
;well as J(HAHB) using IPAP and E.COSY principles

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"d4=1s/(cnst2*4)"
"d22=p3"
"d0=3u"
"DELTA2=d4-larger(p12,p14)/2-50u-p16-d16"
"DELTA3=d4-larger(p12,p14)/2-50u-p16-d16-50u-p16-d16"
"DELTA=p16+d16+50u+p2+d0*2+50u"
"in20=in0*cnst16"
"d20=3u"



1 ze
2 d1 pl1:f1 pl2:f2
  (p3 ph3):f2
  50u UNBLKGRAD
  p16:gp6
  d16
3 (p1 ph1)
  50u 
  p16:gp3
  d16
  DELTA2 pl0:f2 pl0:f1
  4u
  (center (p12:sp2 ph1) (p14:sp3 ph6):f2 )
  4u
  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp3
  d16
  p28 ph1
  (p1 ph2) (p3 ph3):f2

;starts selective j-resolved
  d20
  (center (p13:sp4 ph1) (p24:sp7 ph6):f2 )
  d20
;ends

  d0 
  (p2 ph5)
  d0
  50u
  p16:gp1*EA
  d16 pl0:f2
  d12
  (p24:sp7 ph14):f2
   DELTA pl2:f2
  (p3 ph4):f2
  50u
  p16:gp4
  d16 pl0:f1

  if "cnst25==0"
	{
	(p11:sp1 ph2):f1
	}
	else
	{
	(p11:sp1 ph1):f1
  }

  50u
  p16:gp5
  d16
  DELTA2 pl0:f2 
  
  if "cnst25==0"
	{
	(center (p12:sp2 ph1) (p14:sp3 ph1):f2 )
	}
	else
	{
	(p12:sp2 ph1)
  }

  4u
  DELTA3 pl2:f2 pl1:f1 
  50u
  p16:gp5
  d16

  50u 
  p16:gp2
  d16 BLKGRAD
  

  if "cnst25==0"
	{
	(p3 ph1):f2
	}
	else
	{
	d22
  	}

  go=2 ph31 
  d1 mc #0 to 2 
     F1EA(igrad EA, id0 & id20 & ip3*2 & ip6*2 & ip31*2)
exit
   

ph1=0 
ph2=1
ph3=0 2
ph4=0 0 2 2
ph5=0
ph6=0
ph14=0 0 2 2
ph31=0 2 2 0


;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;sp1: f1 channel - shaped pulse 90 degree for selective excitation A
;sp2: f1 channel - shaped pulse 180 degree for selective inversion A
;sp3: f2 channel - shaped pulse 180 degree for broadband inversion
;sp4: f1 channel - shaped pulse 180 degree for selective inversion B
;sp7: f2 channel - shaped pulse 180 degree for refocussing
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p11: f1 channel - 90 degree shaped pulse for selective excitation A
;p12: f1 channel - 180 degree shaped pulse for selective inversion A
;p13: f1 channel - 180 degree shaped pulse for selective inversion B
;p14: f2 channel - 180 degree shaped pulse for inversion
;p16: homospoil/gradient pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse for broadband refocussing
;p28: f1 channel - trim pulse
;d0 : incremented delay (2D)                         [3 usec]
;d20 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d16: delay for homospoil/gradient recovery
;cnst2: = nJ(XH)
;cnst16: scaling k factor
;cnst25: 0 for IP and 1 for AP
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;in20: = in0
;nd0: 2
;NS: 2 * n
;DS: >= 8
;td1: number of experiments
;FnMODE: echo-antiecho


;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1%
;gpz3: 33%
;gpz4: 50%
;gpz5: 11%
;gpz6: 17%


;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100
;gpnam4: SINE.100
;gpnam5: SINE.100
;gpnam6: SINE.100