;Pulse Program Code for Bruker:

;CLIP-HSQMBC-TOCSY 
;2D proton-selective CLIP-HSQMBC experiment 
;for an esay measurement of long-range 
;proton-carbon coupling constants 

#include <Avance.incl> 
#include <Grad.incl> 
#include <Delay.incl> 


"p2=p1*2"
"d4=1s/(cnst2*4)"
"d11=30m"
"d0=3u"
"in0=inf1/2"
"DELTA1=50u+p16+d16"
"DELTA2=d4-larger(p12,p14)/2-50u-p16-d16"
"DELTA=p16+d16+50u+p2+d0*2+50u"


1 ze
  d11 pl12:f2
2 d1 pl1:f1
3 (p1 ph1)
  50u UNBLKGRAD
  p16:gp3
  d16
  DELTA2 pl0:f2 pl0:f1
  4u
  (center (p12:sp2 ph1) (p14:sp3 ph6):f2 )
  4u
  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp3
  d16
  (center (p1 ph2):f1 (p3 ph3):f2 ) 
  d0 
  (p2 ph5)
  d0
  50u
  p16:gp1*EA
  d16 pl0:f2
  d12
  (p24:sp7 ph4):f2
   DELTA pl2:f2
  (p3 ph4):f2
  50u
  p16:gp4
  d16
  (p1 ph1):f1
  50u
  p16:gp5
  d16
  DELTA2 pl0:f2 pl0:f1
  (center (p12:sp2 ph1) (p14:sp3 ph1):f2 )
  DELTA2 pl2:f2 pl1:f1 
  50u
  p16:gp5

  (p1 ph1):f1 

;starts tocsy 
  
  d12 pl10:f1 

4 p6*3.556 ph22 
  p6*4.556 ph24 
  p6*3.222 ph22 
  p6*3.167 ph24 
  p6*0.333 ph22 
  p6*2.722 ph24 
  p6*4.167 ph22 
  p6*2.944 ph24 
  p6*4.111 ph22 
   
  p6*3.556 ph24 
  p6*4.556 ph22 
  p6*3.222 ph24 
  p6*3.167 ph22 
  p6*0.333 ph24 
  p6*2.722 ph22 
  p6*4.167 ph24 
  p6*2.944 ph22 
  p6*4.111 ph24 

  p6*3.556 ph24 
  p6*4.556 ph22 
  p6*3.222 ph24 
  p6*3.167 ph22 
  p6*0.333 ph24 
  p6*2.722 ph22 
  p6*4.167 ph24   
  p6*2.944 ph22 
  p6*4.111 ph24 
  
  p6*3.556 ph22 
  p6*4.556 ph24 
  p6*3.222 ph22 
  p6*3.167 ph24 
  p6*0.333 ph22 
  p6*2.722 ph24 
  p6*4.167 ph22 
  p6*2.944 ph24 
  p6*4.111 ph22 
  lo to 4 times l1 
             
  5u pl0:f1 
  300u gron6 
  p13:sp4:f1 ph7 
  100u groff 
  d16 
   
;end tocsy 
  
  4u pl1:f1 
  p1 ph1 
  DELTA1 
  (p2 ph1):f1 
  50u  
  p16:gp2 
  d16 BLKGRAD   

  (p3 ph1):f2 

  
 go=2 ph31  
 d1 mc #0 to 2  
     F1EA(igrad EA, id0 & ip3*2 & ip6*2 & ip31*2) 

   

ph1=0  
ph2=1 
ph3=0 2 
ph4=0  
ph5=0 
ph6=0 
ph7=0 
ph14=0 
ph22=3 
ph24=1 
ph31=0 2  


;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl3 : f3 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;sp3: f2 channel - shaped pulse 180 degree for inversion
;sp7: f2 channel - shaped pulse 180 degree for refocussing
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p14: f2 channel - 180 degree shaped pulse for inversion
;p16: homospoil/gradient pulse
;p22: f3 channel - 180 degree high power pulse
;p24: f2 channel - 180 degree shaped pulse for refocussing
;d0 : incremented delay (2D)                         [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J)XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 1 * n
;DS: >= 16
;td1: number of experiments 
;FnMODE: echo-antiecho 

;use gradient ratio: 
;gpz1: 80% 
;gpz2: 20.1% for C-13 
;gpz3: 33%  
;gpz4: 50%  
;gpz5: 17% 
;gpz6: ca. 3% 

;use gradient files:    
;gpnam1: SINE.100 
;gpnam2: SINE.100 
;gpnam3: SINE.100 
;gpnam4: SINE.100 
;gpnam5: SINE.100