;Pulse Program Code for Bruker:

;U&D selHSQMBC-TOCSY without gradient coherence selection
;1D proton-selective 
;for the fast, easy and accurate determination of J(HX)


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"p2=p1*2"
"p4=p3*2"
"d4=1s/(cnst2*4)"
"d20=p3"
"d0=3u" 
"d11=30m"
;"in0=inf1/2"

"DELTA2=d4-larger(p12,p4)/2-50u-d16-p16"

"FACTOR1=(d9/p6*115.112)/2+0.5"
"l1=FACTOR1*2"


1 ze
  d11 
2 d1 pl1:f1 pl2:f2 
3 (p1 ph1)
  50u UNBLKGRAD
  p16:gp3
  d16 pl0:f1
  DELTA2 
  (center (p12:sp2 ph1) (p4 ph1):f2 )
  DELTA2 pl1:f1
  50u 
  p16:gp3
  d16 
  (center (p1 ph2) (p3 ph3):f2 )
  d12
  (p3 ph4):f2
 
  ;begin DIPSI2

  5u pl10:f1

4 p6*3.556 ph22
  p6*4.556 ph24
  p6*3.222 ph22
  p6*3.167 ph24
  p6*0.333 ph22
  p6*2.722 ph24
  p6*4.167 ph22
  p6*2.944 ph24
  p6*4.111 ph22
  
  p6*3.556 ph24
  p6*4.556 ph22
  p6*3.222 ph24
  p6*3.167 ph22
  p6*0.333 ph24
  p6*2.722 ph22
  p6*4.167 ph24
  p6*2.944 ph22
  p6*4.111 ph24

  p6*3.556 ph24
  p6*4.556 ph22
  p6*3.222 ph24
  p6*3.167 ph22
  p6*0.333 ph24
  p6*2.722 ph22
  p6*4.167 ph24
  p6*2.944 ph22
  p6*4.111 ph24

  p6*3.556 ph22
  p6*4.556 ph24
  p6*3.222 ph22
  p6*3.167 ph24
  p6*0.333 ph22
  p6*2.722 ph24
  p6*4.167 ph22
  p6*2.944 ph24
  p6*4.111 ph22
  lo to 4 times l1
                                        	;end DIPSI2
  
  
  5u pl0:f1
  300u gron0
  p13:sp4:f1 ph7
  100u groff
  d16 pl1:f1
  
  (p1 ph1):f1 
  d12
    
   go=2 ph31 
  d1 mc #0 to 2 F1PH(ip6 & ip3)
   exit

   
ph1=0 
ph2=1
ph3=0 2
ph4=0 
ph5=0
ph6=0
ph7=0
ph22=3
ph24=1
ph31=0 2 
  
;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse
;d0 : incremented delay (2D)                  [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J) long range XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho


;for z-only gradients:
;gpz3: 17 %
;gpz6: 3%

;use gradient files:   
;gpnam3: SINE.100
;gpnam6: SINE.100