;Pulse Program Code for Bruker:

;L&R selHSQMBC-TOCSY  with gradient coherence selction
;1D proton-selective 
;for the fast, easy and accurate determination of J(HX)


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"p2=p1*2"
"p4=p3*2"
"d4=1s/(cnst2*4)"
"d20=p3"
"d0=3u" 
"d11=30m"
;"in0=inf1/2"

"DELTA2=d4-larger(p12,p4)/2-50u-d16-p16"
"DELTA1=p16+d16+50u"

"FACTOR1=(d9/p6*115.112)/2+0.5"
"l1=FACTOR1*2"


1 ze
  d11 
2 d1 pl1:f1 pl2:f2 
3 (p1 ph1)
  50u UNBLKGRAD
  p16:gp3
  d16 pl0:f1
  DELTA2 
  4u
  (center (p12:sp2 ph1) (p4 ph1):f2 )
  4u
  DELTA2 pl1:f1
  50u 
  p16:gp3
  d16 
  (center (p1 ph2) (p3 ph3):f2 )
  DELTA1
  (p4 ph4):f2
  50u
  p16:gp1*EA
  d16 
  (p3 ph4):f2
  

  if "cnst25==0"
        {    
        (p1 ph2):f1
        }
        else
        {  
        (p1 ph1):f1
  }

  50u
  p16:gp5
  d16 pl0:f1
  DELTA2

if "cnst25==0"
        {
        (center (p12:sp2 ph1):f1 (p4 ph1):f2)
        }
        else 
        {
        (p12:sp2 ph1)
        }        
  
  DELTA2
  50u 
  p16:gp5
  d16 pl1:f1
  
  (p1 ph1):f1

 
  ;begin DIPSI2

  5u pl10:f1

4 p6*3.556 ph22
  p6*4.556 ph24
  p6*3.222 ph22
  p6*3.167 ph24
  p6*0.333 ph22
  p6*2.722 ph24
  p6*4.167 ph22
  p6*2.944 ph24
  p6*4.111 ph22
  
  p6*3.556 ph24
  p6*4.556 ph22
  p6*3.222 ph24
  p6*3.167 ph22
  p6*0.333 ph24
  p6*2.722 ph22
  p6*4.167 ph24
  p6*2.944 ph22
  p6*4.111 ph24

  p6*3.556 ph24
  p6*4.556 ph22
  p6*3.222 ph24
  p6*3.167 ph22
  p6*0.333 ph24
  p6*2.722 ph22
  p6*4.167 ph24
  p6*2.944 ph22
  p6*4.111 ph24

  p6*3.556 ph22
  p6*4.556 ph24
  p6*3.222 ph22
  p6*3.167 ph24
  p6*0.333 ph22
  p6*2.722 ph24
  p6*4.167 ph22
  p6*2.944 ph24
  p6*4.111 ph22
  lo to 4 times l1
                                        	;end DIPSI2
  
  
  5u pl0:f1
  300u gron0
  p13:sp4:f1 ph7
  100u groff
  d16
  
  5u pl1:f1
  
  (p1 ph1):f1 
  DELTA1
  (p2 ph1):f1
  50u
  p16:gp2
  d16 BLKGRAD
  
  if "cnst25==0"
        {
        d12 
        (p3 ph1):f2
        }
        else 
        {
        d20
  }        
 
  go=2 ph31 
  d1 mc #0 to 2 
  F1EA(igrad EA, id0 & ip3*2 & ip6*2 & ip31*2)
  exit

   
ph1=0 
ph2=1
ph3=0 2
ph4=0 
ph5=0
ph6=0
ph7=0
ph22=3
ph24=1
ph31=0 2 
  
;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p4 : f2 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse
;d0 : incremented delay (2D)                  [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d4 : 1/(4J) long range XH
;d11: delay for disk I/O                             [30 msec]
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;inf1: 1/SW(X) = 2 * DW(X)
;in0: 1/(2 * SW(X)) = DW(X)
;NS: 1 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho

;use gradient ratio:	gp 1 : gp 2
;                          80 : 20.1 : 33 : 50 : 17 : 11  for C-13
;                          80 :  8.1 : 33 : 50 : 17 : 11  for N-15

;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13, 8.1% for N-15
;gpz3: 17 %
;gpz6: 3%

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam3: SINE.100
;gpnam6: SINE.100