;Pulse Program Code for Bruker:

;iINEPT-HSQC

;Shift Correlation version => cnst1= 0

;J-resolved version =>cnst1= 1

;F1-heterocoupled iINEPT HSQC by using initial 13C Boltzmann polarization

;for determination of 1J CH via splitting in F1

;phase sensitive using Echo/Antiecho-TPPI gradient selection

;with decoupling during acquisition

;using shaped pulses for inversion and refocussing on f2 - channel

;using G\_BIRD(r) to remove long range couplings in t1

;with J scaling in t1

;Measurement of individual 1J(CH) coupling constants in diastereotopic CH2 groups.

;Simultaneous sign-sensitive determination of 1J(CHA), 1J(CHB) and 2J(HH) from a single cross-peak.

;Simultaneous measurement of residual dipolar 1D(CH) and 2D(HH) couplings.

;J. Saurí, L.Castañar, P. Nolis, A. Virgili and T. Parella: Straightforward measurement of individual 1J(CH) and 2J(HH) in diastereotopic CH2 groups.

;J. Magn. Reson. 2014, 242, 33-40. http://dx.doi.org/10.1016/j.jmr.2014.02.003

;$CLASS=HighRes

;$DIM=2D

;$TYPE=

;$SUBTYPE=

;$COMMENT=

;Avance III

;Topspin3.1

#include <Avance.incl>

#include <Grad.incl>

#include <Delay.incl>

#include <De.incl>

"p2=p1\*2"

"p4=p3\*2"

"d2=1s/(cnst2\*2)"

"d4=1s/(cnst2\*4)"

"d11=30m"

"d0=3u"

"d20=3u"

"in0=inf1/2"

"in20=in0\*cnst16"

"DELTA=d0\*2+p2+p16+d16-p3\*4/PI"

"DELTA1=p16+d16-p3\*4/PI"

"DELTA2=d4-larger(p2,p14)/2"

"DELTA3=d2-larger(p2,p39)/2"

"DELTA4=d4-p16-d16-larger(p2,p14)/2"

"acqt0=0"

baseopt\_echo

1 ze

d12 do:f1

2 d11 do:f2

d12 pl11:f1

d1 cpd1:f1

d12 do:f1

d12 pl1:f1

d12 pl2:f2 UNBLKGRAD

(p3 ph3):f2

if "cnst1==0"

{

d20

(p1 ph1)

DELTA3

(center (p2 ph1) (p39:sp4 ph1):f2 )

DELTA3

(p1 ph1)

d20

d0

(p2 ph1)

d0

p16:gp1\*EA

d16 pl0:f2

(p39:sp4 ph14):f2

DELTA pl2:f2

}

else

{

d0

(p1 ph1)

DELTA3

(center (p2 ph1) (p39:sp4 ph1):f2 )

DELTA3

(p1 ph1)

d0

p16:gp1\*EA

d16 pl0:f2

(p39:sp4 ph14):f2

DELTA1 pl2:f2

}

(ralign (p3 ph4):f2 (p1\*0.4 ph1):f1 )

DELTA2 pl0:f2

(center (p2 ph1) (p14:sp3 ph1):f2 )

DELTA4 pl12:f2

p16:gp2

d16 BLKGRAD

go=2 ph31 cpd2:f2

d11 do:f2 mc #0 to 2

F1EA(calgrad(EA), caldel(d0, +in0) & caldel(d20, +in20) & calph(ph3, +180) & calph(ph31, +180))

exit

ph1=0

ph2=1

ph3=0 2

ph4=0 0 2 2

ph14=0 0 2 2

ph31=0 2 2 0

;pl0 : 120dB

;pl1 : f1 channel - power level for pulse (default)

;pl2 : f2 channel - power level for pulse (default)

;pl12: f2 channel - power level for CPD/BB decoupling

;sp3: f2 channel - shaped pulse 180 degree for inversion

;sp4: f2 channel - shaped pulse 180 degree for refocussing

;p1 : f1 channel - 90 degree high power pulse

;p2 : f1 channel - 180 degree high power pulse

;p3 : f2 channel - 90 degree high power pulse

;p14: f2 channel - 180 degree shaped pulse for inversion

; Crp60,0.5,20.1

;p16: homospoil/gradient pulse

;p28: f1 channel - trim pulse

;p39: f2 channel - 180 degree shaped pulse for refocussing

; Bip720,100,10.1 (160us at 600.13 MHz)

;d0 : incremented delay (2D) [3 usec]

;d1 : relaxation delay; 1-5 \* T1

;d2 : 1/(2J)XH

;d4 : 1/(4J)XH

;d11: delay for disk I/O [30 msec]

;d16: delay for homospoil/gradient recovery

;inf1: 1/SW(X) = 2 \* DW(X)

;in0: 1/(2 \* SW(X)) = DW(X)

;nd0: 2

;NS: 2 \* n

;DS: >= 16

;td1: number of experiments

;FnMODE: echo-antiecho

;cpd1: Saturation according to sequence defined by cpdprg1 [walt16]

;cpd2: decoupling according to sequence defined by cpdprg2 [p5m4sp180.2]

;pcpd1: f1 channel - 90 degree pulse for decoupling sequence

;pcpd2: f2 channel - 90 degree pulse for decoupling sequence

;cnst1: correlation (0)/J-resolved (1)

;cnst2: = J(XH)

;cnst16: = J(scale) factor

;use gradient ratio: gp 1 : gp 2

; 80 : 20.1 for C-13

; 80 : 8.1 for N-15

;for z-only gradients:

;gpz1: 80%

;gpz2: 20.1% for C-13, 8.1% for N-15

;use gradient files:

;gpnam1: SINE.100

;gpnam2: SINE.100

;preprocessor-flags-start

;LABEL\_CN: for C-13 and N-15 labeled samples start experiment with

; option -DLABEL\_CN (eda: ZGOPTNS)

;preprocessor-flags-end

;$Id: iINEPT,v 3.1 2014/10/10 16:34:30 lau Exp $