;only for topspin 1.3 version

;mf\_hmbctocsy  
;HMBC  
;2D H-1/X correlation via heteronuclear zero and double quantum coherence  
;optimized on long range couplings  
;with low-pass J-filter to suppress one-bond correlations  
;no decoupling during acquisition  
;using gradient pulses for selection  
  
  
#include <Avance.incl>  
#include <Grad.incl>  
#include <Delay.incl>  
  
    
"p5=p6\*.667"  
"p7=p6\*2"  
"p2=p1\*2"  
"d0=3u"  
"d13=3u"  
"d6=1s/(cnst13\*2)"  
"DELTA1=50u+p16+d16+4u"  
"SCALEF=p7\*2/p5+0.5"  
"FACTOR1=((d9-p17\*2)/(p6\*64+p5))/SCALEF+0.5"  
"l1=FACTOR1\*SCALEF"  
  
1 ze   
2 d1   
3 d12 pl1:f1  
  p1 ph1  
  d6  
  p3:f2 ph4  
  d0  
  50u UNBLKGRAD  
  p16:gp1  
  d16  
  p2 ph2  
  50u  
  p16:gp2  
  d16   
  d0  
  p3:f2 ph5  
  goscnp ph31  
  50u wr #1   
  p16:gp3  
  d16  
  4u pl10:f1  
  (p17 ph26)  
                        ;begin MLEV17  
4 (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph22 p7 ph23 p6 ph22)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p6 ph24 p7 ph25 p6 ph24)  
  (p5 ph23)  
  lo to 4 times l1   
                        ;end MLEV17  
  (p17 ph26)   
  50u  
  p16:gp3\*-1  
  d16 BLKGRAD  
  gosc  ph31   
  d1 wr #2   
  lo to 3 times 2  
  10m if #1   
  10m if #2  
  10m id0    
  lo to 3 times td1    
exit   
    
  
ph1=0   
ph11=1  
ph2=0   
ph3=0   
ph4=0 2  
ph5=0 0 2 2   
ph22=3   
ph23=0   
ph24=1   
ph25=2   
ph26=0   
ph31=0 2 2 0  
  
  
  
;pl1 : f1 channel - power level for pulse (default)  
;pl2 : f2 channel - power level for pulse (default)  
;p1 : f1 channel -  90 degree high power pulse  
;p2 : f1 channel - 180 degree high power pulse  
;p3 : f2 channel -  90 degree high power pulse  
;p16: homospoil/gradient pulse  
;d0 : incremented delay (2D)                  [3 usec]  
;d1 : relaxation delay; 1-5 \* T1  
;d2 : 1/(2J)XH  
;d6 : delay for evolution of long range couplings  
;d16: delay for homospoil/gradient recovery  
;cnst2: = J(XH)  
;cnst13: = J(XH) long range  
;in0: 1/(2 \* SW(X)) = DW(X)  
;nd0: 2  
;NS: 2 \* n  
;DS: 16  
;td1: number of experiments  
;FnMODE: QF  
  
  
;use gradient ratio:     gp 1 : gp 2 : gp 3  
;              50 :   30 : 40.1   for C-13  
;              70 :   30 : 50.1   for N-15  
  
;for z-only gradients:  
;gpz1: 50% for C-13, 70% for N-15  
;gpz2: 30%  
;gpz3: 40.1% for C-13, 50.1% for N-15  
  
;use gradient files:     
;gpnam1: SINE.100  
;gpnam2: SINE.100  
;gpnam3: SINE.100  
  
  
  
;$Id: hmbcgplpndqf,v 1.2 2002/07/16 12:41:02 ber Exp $