;mf\_hsqc

;MFA-HSQC/HSQC

#include <Avance.incl>

#include <Grad.incl>

#include <Delay.incl>

"p2=p1\*2"

"p4=p3\*2"

"d0=3u"

"d4=1s/(cnst2\*4)"

"d11=30m"

"DELTA1=p16+d16+8u"

"DELTA2=d4-larger(p2,p14)/2"

"DELTA3=d24-p19-d16"

"DELTA4=d4-larger(p2,p14)/2-p16-d16"

"DELTA5=d4-larger(p2,p14)/2-p16-d16-p16-d16"

"DELTA=d21-p16-d16-p2-d0\*2"

"l0=td1/2"

1 ze

 d11 pl12:f2

2 d1 do:f2

3(p1 ph1)

 DELTA2 pl0:f2

 4u

(center (p2 ph1) (p14:sp3 ph6):f2 )

4u

DELTA2 pl2:f2 UNBLKGRAD

(p1 ph2) (p3 ph3):f2

d0

(p2 ph7)

d0

p16:gp1\*EA

d16

DELTA

(center (p2 ph1) (p4 ph4):f2 )

d21

(center (p1 ph1) (p3 ph4):f2 )

p19:gp3

d16

DELTA3

(center (p2 ph1) (p4 ph1):f2 )

DELTA3

p19:gp3

d16

(center (p1 ph2) (p3 ph5):f2 )

p16:gp4

d16

DELTA4 pl0:f2

(center (p2 ph1) (p14:sp3 ph1):f2 )

DELTA4

p16:gp6

d16 pl12:f2

4u BLKGRAD

goscnp ph31 cpd2:f2

d12 do:f2

d12 wr #1

4u UNBLKGRAD

p16:gp5

d16

p1 ph1

DELTA1

(p2 ph1)

50u pl12:f2

p16:gp2

d16 BLKGRAD

gosc ph31 cpd2:f2

d12 do:f2

d1 wr #2

lo to 3 times 2

d12 if #1

d12 zd

d12 if #2

30u igrad EA

30u ip3\*2

30u ip6\*2

30u ip31\*2

lo to 3 times 2

30u id0

lo to 3 times l0

exit

ph1=0

ph2=1

ph3=0 2

ph4=0 0 2 2

ph5=1 1 3 3

ph6=0

ph7=0 0 2 2

ph8=3

ph9=2

ph31=2 0 0 2

;pl0 : 120dB

;pl1 : f1 channel - power level for pulse (default)

;pl2 : f2 channel - power level for pulse (default)

;pl3 : f3 channel - power level for pulse (default)

;pl12: f2 channel - power level for CPD/BB decoupling

;sp3: f2 channel - shaped pulse 180 degree

;p1 : f1 channel - 90 degree high power pulse

;p2 : f1 channel - 180 degree high power pulse

;p3 : f2 channel - 90 degree high power pulse

;p4 : f2 channel - 180 degree high power pulse

;p14: f2 channel - 180 degree shaped pulse for inversion

;p16: homospoil/gradient pulse

;p19: gradient pulse 2 [500 usec]

;p22: f3 channel - 180 degree high power pulse

;p28: f1 channel - trim pulse

;d0 : incremented delay (2D) [3 usec]

;d1 : relaxation delay; 1-5 \* T1

;d4 : 1/(4J)XH

;d11: delay for disk I/O [30 msec]

;d16: delay for homospoil/gradient recovery

;d21: set d21 according to multiplicity selection

; 1/(2J(XH)) XH, XH3 positive, XH2 negative

;d24: 1/(8J)XH for all multiplicities

; 1/(4J)XH for XH

;cnst2: = J(XH)

;in0: 1/(2 \* SW(X)) = DW(X)

;nd0: 2

;NS: 2 \* n

;DS: >= 16

;td1: number of experiments

;FnMODE: echo-antiecho

;cpd2: decoupling according to sequence defined by cpdprg2

;pcpd2: f2 channel - 90 degree pulse for decoupling sequence

;for z-only gradients:

;gpz1: 80%

;gpz2: 20.1%

;gpz3: 11%

;gpz4: -5%

;gpz5: 33%

;gpz6: 15.1%