Bruker pulse program:
;2jhh-res
;2JHH-resolved HSQC

#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>
#include <De.incl>

"d22=d2-larger(p2,p14)/2"

"p2=p1*2"
"d0=3u"
"d20=3u"
"d21=3u"
"d2=1s/(cnst2*2)"
"d4=1s/(cnst2*4)"

"in0=inf1/2"
"in20=in0*cnst20"
"in21=in0*cnst21"

"DELTA=p16+d16+p2+d21*2-4u"
"DELTA2=d4-p14/2-4u"
"DELTA3=p16+d16+50u"
"DELTA4=d4-p14/2-4u-p16-d16"
"DELTA5=d2-larger(p2,p14)/2"

"count=(aq/d19)-1"
"acqt0=0"
baseopt_echo

1 ze
2 d1 do:f2
  d12 pl1:f1
3 (p1 ph1)
  DELTA2 pl0:f2
  4u
  (center (p2 ph1) (p14:sp3 ph6):f2 )
  4u
  p28 ph1
  DELTA2 pl2:f2 UNBLKGRAD
  (center (p1 ph2) (p3 ph3):f2 )
  d21
  (p2 ph1)
  d21


  p16:gp1*EA
  d16 pl0:f2
  (p24:sp7 ph4):f2
  4u
  DELTA pl2:f2
  
  (center (p1 ph1) (p3 ph4):f2 )
  DELTA2 pl0:f2
  4u
  (center (p2 ph1) (p14:sp3 ph1):f2 )
  4u
  DELTA2
    
  d20
  p1 ph1
  DELTA5 pl0:f2
  (center (p2 ph1) (p14:sp3 ph6):f2 )
  DELTA5 pl2:f2
  p1 ph1
  (p4 ph1):f2    ;OPTIONAL for specific 2JHH-J-resolved spectrum
  d20

  p1 ph2
  d12 pl5:f1
  300u gron0
  p32:sp29:f1 ph1
  100u groff
  d16 
  d12 pl1:f1
  p1 ph1

  DELTA3
  p2 ph1
  50u
  p16:gp2
  d16 BLKGRAD

d12 pl12:f2
go=2 ph31 cpd2:f2


  d1 do:f2 mc #0 to 2 
   F1EA(calgrad(EA), caldel(d0, +in0) & caldel(d20, +in20) & caldel(d21, +in21))
exit



ph1=0 
ph2=1
ph3=0 2
ph4=0 
ph6=0
ph7=2

ph15=1 
ph16=2 
ph17=3 

ph25=2
ph26=3
ph27=0

ph30=0
ph31=0 2 
 

;pl0 : 120dB
;pl1 : f1 channel - power level for pulse (default)
;pl2 : f2 channel - power level for pulse (default)
;pl10: f1 channel - power level for TOCSY-spinlock
;sp3: f2 channel - shaped pulse 180 degree
;spnam3: Crp60,0.5,20.1
;sp7: f2 channel - shaped pulse (180degree refocussing)
;spnam7: Crp60comp.4
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p3 : f2 channel -  90 degree high power pulse
;p14: f2 channel - 180 degree shaped pulse for inversion
;     = 500usec for Crp60,0.5,20.1
;p16: homospoil/gradient pulse                         [1 msec]
;p24: f2 channel - 180 degree shaped pulse for refocussing
;     = 2msec for Crp60comp.4
;d0 : incremented delay (2D)                           [3 usec]
;d1 : relaxation delay; 1-5 * T1
;d2 : 1/(2J(XH))
;d4 : 1/(4J(XH))
;d16: delay for homospoil/gradient recovery
;cnst2: = J(XH)
;cnst15: = conventional(0)/pure shift(1)
;cnst14: = conventional(0)/2JHH-resolved(1)
;cnst17: = -0.5 for Crp60comp.4
;cnst20: = J(scale) factor 
;cnst21: = Correlation factor
;in0: 1/(2 * SW(X)) = DW(X)
;nd0: 2
;NS: 2 * n
;DS: >= 16
;td1: number of experiments
;FnMODE: echo-antiecho


;use gradient ratio:	gp 1 : gp 2 : gp 0
;			  80 : 20.1 :   11   for C-13

;for z-only gradients:
;gpz1: 80%
;gpz2: 20.1% for C-13
;gpz0: 11%

;use gradient files:   
;gpnam1: SINE.100
;gpnam2: SINE.100